Squirrel array reduce() example

array.reduce.device.nut

local sourceArray = [10, 21, 30, 43];

// Combine all the values in the array
local reduction = sourceArray.reduce(function(previousValue, currentValue){
    return (previousValue + currentValue);
});

server.log(reduction);
// Displays "104"

array.reduce.lambda.device.nut

local sourceArray = [10, 21, 30, 43];

// Combine all the values in the array
local reduction = sourceArray.reduce(@(p, c) p + c);

server.log(reduction);
// Displays "104"

array.reduce.pem.agent.nut

// Decode an X.509 certificate .pem file
// Remove the armor, concatenate the lines and base64 decode the text
function decodePem(pemString) {
    local lines = split(pemString, "\n");
    // We really ought to iterate over the array until we find a starting line,
    // and then look for the matching ending line, rather than assuming its on line 0
    if ((lines[0] == "-----BEGIN PRIVATE KEY-----" && 
       lines[lines.len() - 1] == "-----END PRIVATE KEY-----") ||
      (lines[0] == "-----BEGIN RSA PRIVATE KEY-----" && 
       lines[lines.len() - 1] == "-----END RSA PRIVATE KEY-----") ||
      (lines[0] == "-----BEGIN PUBLIC KEY-----" && 
       lines[lines.len() - 1] == "-----END PUBLIC KEY-----")) {
          
        local all = lines.slice(1, lines.len() - 1).reduce(@(a, b) a + b);
          return http.base64decode(all);
    }

    return null;
}