flac-git_PKGBUILD

# $Id: PKGBUILD 255141 2015-12-10 04:45:28Z foutrelis $
# Maintainer: Kamran Mackey <kamranm1200@gmail.com>

pkgbase=flac-git
pkgname=('flac-git' 'flac-doc-git')
pkgver=1.3.3.r3936.b358381a
pkgrel=1
arch=('x86_64' 'aarch64')
url="https://xiph.org/flac/"
license=('BSD' 'GPL')
depends=('gcc-libs' 'libogg')
makedepends=('nasm' 'doxygen')
options=('!makeflags')
source=(git://github.com/xiph/flac.git)
sha1sums=('SKIP')
_gitname=flac

pkgver() {
  cd "$srcdir"/"$_gitname"
  if [ -e "$srcdir/flac-version.txt" ]; then
        printf "$(cat "$srcdir/flac-version.txt").r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  else
        printf "1.3.3.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  fi
}



build() {
  cd "$srcdir"/"$_gitname"
  ./autogen.sh
  ./configure --prefix=/usr --disable-sse
  make
  make DESTDIR="$srcdir/$_gitname/pref" install && cd pref/usr/bin/ && ./flac -v | sed 's/flac //g' > $srcdir/flac-version.txt && cd $srcdir/"$_gitname" && rm -r $srcdir/"$_gitname"/pref
  
  pkgver
}

package_flac-git() {
  pkgdesc="Free Lossless Audio Codec (git version)"
  options=('!docs')
  conflicts=('flac')
  provides=('flac' 'libFLAC.so' 'libFLAC++.so')

  cd "$_gitname"
  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYING.Xiph "${pkgdir}/usr/share/licenses/$_gitname/LICENSE"
}

package_flac-doc-git() {
  pkgdesc="Developer documentation for the Free Lossless Audio Codec (git version)"
  depends=('flac')
  conflicts=('flac-doc')
  provides=('flac-doc')

  cd "$_gitname"
  make DESTDIR="${pkgdir}" -C doc install
  sed -i "s|$srcdir/$_gitname|/usr|" "${pkgdir}/usr/share/doc/$_gitname/FLAC.tag"
}