Obfuscate jar from java-library gradle projects

build.gradle

import proguard.gradle.ProGuardTask
import java.nio.file.Paths

dependencies {
  [...]
  // Required by @task::obfuscate
  compileOnly 'org.jetbrains:annotations:13.0'
}

def jarNameWithoutExtension = jar.archiveName.with { it.take(it.lastIndexOf(".")) }
def obfuscatedJarName = "${jarNameWithoutExtension}-release.jar"
def jarFileLocation = jar.archivePath.parent
def obfuscatedFilePath = Paths.get(jarFileLocation, obfuscatedJarName)

task obfuscate(type: ProGuardTask) {
    configuration 'proguard-rules.pro' // Use the standard proguard file from gradle projects

    injars jar.archivePath
    outjars obfuscatedFilePath.toString()

    libraryjars "${System.getProperty('java.home')}/lib/rt.jar"
    libraryjars configurations.findByName('runtimeClasspath').getFiles() // Add all libraries from dependencies

    doLast {
        jar.archivePath.renameTo(Paths.get(jarFileLocation, "$jarNameWithoutExtension-original.jar").toFile())

        obfuscatedFilePath.toFile().renameTo(jar.archivePath) // Rename obfuscated jar to the original name
    }
}

jar.finalizedBy(project.tasks.obfuscate)