Godot Viewport Input from Raycast (Useful for VR)

Area.gd

extends Area

onready var viewport = $"../Viewport"
onready var collion = $CollisionShape
var last_collided = Vector3.ZERO
var mouse_mask = 0
var mesh_size_x = 0.5
var mesh_size_y = 0.5
var uv_offset_x = -0.1
var uv_offset_y = -0.1


func global_to_viewport(point):
    var t = collion.global_transform
    var at = t.xform_inv(point)

    var half = 0.5
    at.x = ((at.x / mesh_size_x) + half + uv_offset_x) * viewport.size.x
    at.y = (half - (at.y / mesh_size_y) + uv_offset_y) * viewport.size.y

    return Vector2(at.x, at.y)


func _on_pointer_moved(point):
    if point != last_collided:
        var at = global_to_viewport(point)
        var from = global_to_viewport(last_collided)
        last_collided = point

        var event = InputEventMouseMotion.new()
        event.set_position(at)
        event.set_global_position(at)
        event.set_relative(at - from)
        event.set_button_mask(mouse_mask)

        viewport.input(event)
        

Input.gd

extends Node

onready var raycast = $RayCast


func _process(delta):
    var target = raycast.get_collider()
    if target and target.has_method("_on_pointer_moved"):
        target._on_pointer_moved(raycast.get_collision_point())