Expand a EXT4 additional VHD in WSL2

vhd_expand.bat

@echo off

set VHD_PATH=D:\data.vhdx
set NEW_SIZE_GB=2048
set MOUNT_NAME=data
set WSL_DIST=Ubuntu

set /a NEW_SIZE_MB=%NEW_SIZE_GB%*1024

echo:
echo ========== Expand VHD ==========
echo:

echo select vdisk file="%VHD_PATH%" > vhd_expand_diskpart.txt
echo detail vdisk >> vhd_expand_diskpart.txt
echo expand vdisk maximum=%NEW_SIZE_MB% >> vhd_expand_diskpart.txt
echo detail vdisk >> vhd_expand_diskpart.txt
echo exit >> vhd_expand_diskpart.txt

diskpart /s vhd_expand_diskpart.txt

del /f /q vhd_expand_diskpart.txt

echo:
echo ========== Expand File System ==========
echo:

wsl -d %WSL_DIST% --mount "%VHD_PATH%" --vhd --name %MOUNT_NAME%
echo:

wsl -d %WSL_DIST% -- echo Before: $(df -h ^| grep /mnt/wsl/%MOUNT_NAME%)
echo:
wsl -d %WSL_DIST% -- resize2fs /dev/$(lsblk ^| grep /mnt/wsl/%MOUNT_NAME% ^| awk '{print $1}') %NEW_SIZE_MB%M
echo:
wsl -d %WSL_DIST% -- echo After: $(df -h ^| grep /mnt/wsl/%MOUNT_NAME%)
echo:

wsl -d %WSL_DIST% --unmount %VHD_PATH%

pause