aoc_day5.ex

defmodule Advent2018.Day5 do
  def solve(input) do
    parse_polymers(input, <<>>, nil)
  end

  def parse_polymers(<<>>, acc, _), do: byte_size(acc)

  def parse_polymers(
        <<a::size(2), _::size(1), b::size(5), rest::binary>>,
        seen,
        <<a::size(2), _::size(1), b::size(5)>> = ignore
      ) do
    parse_polymers(rest, seen, ignore)
  end

  def parse_polymers(<<a, rest::binary>>, <<b, seen::binary>>, ignore) when abs(a - b) == 32 do
    parse_polymers(rest, seen, ignore)
  end

  def parse_polymers(<<a, b, rest::binary>>, seen, ignore) when abs(a - b) == 32 do
    parse_polymers(rest, seen, ignore)
  end

  def parse_polymers(<<"\n", rest::binary>>, seen, ignore) do
    parse_polymers(rest, seen, ignore)
  end

  def parse_polymers(<<a, rest::binary>>, seen, ignore) do
    parse_polymers(rest, <<a>> <> seen, ignore)
  end
end

defmodule Advent2018.Day5Part2 do
  def solve(input) do
    Enum.reduce(?a..?z, {nil, nil}, fn chr, {best, best_chr} ->
      len = Advent2018.Day5.parse_polymers(input, <<>>, <<chr>>)

      if !best || len < best do
        {len, chr}
      else
        {best, best_chr}
      end
    end)
  end
end