PKGBUILD_woff-tools

PKGBUILD

# Maintainer: William Gathoye <william + aur at gathoye dot be>
# Maintainer: Jacqueline Fisher <weretiger95@gmail.com>
# Contributor: Tetsumaki <http://goo.gl/YMBdA>
# Contributor: rws <elisp dot vim at google mail> (@xd1le on twitter)

pkgname=woff-tools
provides=('sfnt2woff' 'woff2sfnt')
replaces=('sfnt2woff')
pkgver=20091003
pkgrel=4
pkgdesc="Tools to convert existing TrueType/OpenType fonts to WOFF and inversely (sfnt2woff and woff2sfnt)"
arch=('i686' 'x86_64' 'armv6h')

url="https://people.mozilla.org/~jkew/woff/"
license=('MPL' 'GPL' 'LGPL')
makedepends=('quilt')
# src.: http://superuser.com/a/429625/456258
source=("$pkgname-$pkgver.tar.gz::https://github.com/wget/woff-tools/archive/20091003.tar.gz"
        'patches.tar.gz::https://salsa.debian.org/fonts-team/woff-tools/-/archive/master/woff-tools-master.tar.gz?path=debian/patches')
noextract=('patches.tar.gz')
sha512sums=('0969a7b040ced2c1ba6a5b7d60396141f795ac56fdcdb6c663cc9794fdf08f32b35089934b0da498a6d357372daebbebd5149e78bdb368e2c3b675d2adaa4863'
            '0bcf517c5ff694ded3e310e16ec286500ea2b131e6e228b5b6a48ce62283e656d6b0f2407ba7dc37c8c7e79079fc11f0cb2089fe730060d31a8054e07e606485')

prepare() {
    cd $pkgname-$pkgver
    tar --strip-components=2 -xf $srcdir/patches.tar.gz
    quilt push -a || true
}

build () {
    cd $pkgname-$pkgver
    make
}

package() {
    cd $pkgname-$pkgver/
    install -D sfnt2woff "$pkgdir/usr/bin/sfnt2woff"
    install -D woff2sfnt "$pkgdir/usr/bin/woff2sfnt"
}