PKGBUILD-clap-host

PKGBUILD

# Maintainer: Alexandre BIQUE <bique.alexandre@gmail.com>
pkgname=clap-host
pkgver=1.0.3
pkgrel=1
pkgdesc="CLAP example host"
arch=(x86_64)
url="https://github.com/free-audio/clap-host"
license=('MIT')
groups=()
depends=(qt6-base rtmidi rtaudio hicolor-icon-theme)
makedepends=(cmake ninja catch2 git)
optdepends=()
provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=(git+https://github.com/free-audio/clap-host#tag=$pkgver
  git+https://github.com/free-audio/clap
  git+https://github.com/free-audio/clap-helpers)
noextract=()
sha256sums=(SKIP
  SKIP
  SKIP)

prepare() {
  cd "$pkgname"
  git submodule init
  git config submodule.clap.url "$srcdir/clap"
  git config submodule.clap-helpers.url "$srcdir/clap-helpers"
  git config --remove-section submodule.vcpkg
  git -c protocol.file.allow=always submodule update
}

build() {
  cd "$pkgname"

  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DUsePkgConfig=TRUE \
    -GNinja --preset ninja-system
  cmake --build --preset ninja-system
}

package() {
  cd "$pkgname/builds/ninja-system"

  DESTDIR="$pkgdir/" ninja install

  install -Dm644 "$srcdir/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}