An AutoHotkey script (https://autohotkey.com/) for typing Ithkuil symbols (http://ithkuil.net/)

Ithkuil.ahk

/*
 *  USAGE INSTRUCTIONS
 *  Ctrl + Win + semicolon  Exit
 *  Win + apostrophe        ʰ
 *  Win + comma             âêîôû čňřšž
 *  Win + period            ëöü çļţż
 *  Win + forward slash     áéíóú
 *  Win + backslash         àèìòù
 */

#InstallKeybdHook               ; Better keyboard handling
#NoEnv                          ; Better compatibility
#SingleInstance Force           ; No dialog when restarting
SendMode Input                  ; Faster keystrokes

SoundBeep, 1046.502, 100
SoundBeep, 1567.982, 100

inputMode := 0

typeChar(char) {
  If (GetKeyState("CapsLock", "T") ^ GetKeyState("Shift"))
    StringUpper char, char
  Global inputMode := 0
  ToolTip
  Send %char%
}

Return ; END OF AUTO-EXECUTE SECTION

^#;::
SoundBeep, 391.996, 100
SoundBeep, 261.626, 100
ExitApp

#,::
inputMode := 1
ToolTip âêîôû čňřšž
Return

#.::
inputMode := 2
ToolTip ëöü çļţż
Return

#/::
inputMode := 3
ToolTip áéíóú
Return

#\::
inputMode := 4
ToolTip àèìòù
Return

#'::Send ʰ

#If inputMode != 0
Esc::
inputMode := 0
ToolTip
Return

#If inputMode = 1
*a::typeChar("â")
*e::typeChar("ê")
*i::typeChar("î")
*o::typeChar("ô")
*u::typeChar("û")
*c::typeChar("č")
*n::typeChar("ň")
*r::typeChar("ř")
*s::typeChar("š")
*z::typeChar("ž")

#If inputMode = 2
*e::typeChar("ë")
*o::typeChar("ö")
*u::typeChar("ü")
*c::typeChar("ç")
*l::typeChar("ļ")
*t::typeChar("ţ")
*z::typeChar("ż")

#If inputMode = 3
*a::typeChar("á")
*e::typeChar("é")
*i::typeChar("í")
*o::typeChar("ó")
*u::typeChar("ú")

#If inputMode = 4
*a::typeChar("à")
*e::typeChar("è")
*i::typeChar("ì")
*o::typeChar("ò")
*u::typeChar("ù")