profile all functions in a namespace

deps.edn

{:paths ["."] :deps {robert/hooke       {:mvn/version "1.3.0"}
                     com.taoensso/tufte {:mvn/version "2.0.1"}}}

profile_ns.clj

(ns profile-ns
  (:require [taoensso.tufte :as tufte :refer [p]]
            [robert.hooke :as hooke]))

(defn profile-ns
  ([namespace-name]
    (profile-ns {:enable true} namespace-name))
  ([{profile? :enable} namespace-name]
   (doseq [[_ v]
           (filter
             (fn [[_ x]]
               (if (and (var? x) (fn? @x)) (-> x meta :ns ns-name #{namespace-name}) false))
             (ns-map namespace-name))]
     (hooke/remove-hook v :p)
     (when profile?
       (hooke/add-hook v :p
         (fn [f & args]
           (p (keyword (name namespace-name) (name (:name (meta v))))
              (apply f args))))))))

You want to profile all functions in a namespace, this uses Tufte and Robert Hooke to make that so:

(use 'profile-ns)
(require '[taoensso.tufte :as tufte])

(profile-ns 'my-name-space)
(tufte/format-pstats @(last (tufte/profiled {} (my-function))))

profile-ns all the namespaces to the level of detail you want to be included in the results

(profile-ns {:enable false} 'my-name-space) to disable profiling from a namespace

:profiling
    {
       :extra-deps
       {
          profile-ns {:git/url "https://gist.github.com/Hendekagon/75139bb285ccd8cc183fe69415ccc66f" 
                            :sha "347094bf0fafb51c7d4bb1362646e35cc3efe8c6"}
       }
    }