Creates the M-code for an empty table based on a table schema (Table.Schema).

Text.CreateEmptyTableFromSchema.pq

let
    fnFormatted = let
    func = (myTable as table) =>
        let
            #"Table1 Schema" = Table.Schema(myTable),
            TypesList = Table.AddColumn(
                #"Table1 Schema",
                "TypeRecord",
                each [Name] & "=" & [TypeName]
            )[TypeRecord],
            TypeRecordString = "[" & Text.Combine(TypesList, ", ") & "]",
            TableString = "#table(type table "
                & TypeRecordString
                & ", {{"
                & Text.Combine(List.Repeat({"null"}, List.Count(TypesList)), ", ")
                & "}})"
        in
            TableString,
    documentation = [
        Documentation.Name = " Text.CreateEmptyTableFromSchema ",
        Documentation.Description
            = " Creates the M-code for an empty table based on a table schema. ",
        Documentation.LongDescription
            = " Creates the M-code for an empty table based on a table schema (Table.Schema). ",
        Documentation.Category = " Text.Transformations ",
        Documentation.Source = " www.TheBIcountant.com https://wp.me/p6lgsG-2tJ . ",
        Documentation.Version = " 1.0 ",
        Documentation.Author = " Imke Feldmann ",
        Documentation.Examples = {

[Description = "  ",
 Code = 
 " let
    myTable = #table( type table [myText = Text.Type, myNumber = Int64.Type, myDate = Date.Type], 
 
//  myText| myNumber|            myDate| 
{//-------|---------|------------------|  
{      ""A"",       10, #date(2022, 01, 01) } } ),

    FunctionCall = fnText_CreateEmptyTableFromSchema( myTable )
in
    FunctionCall "
                  ,
Result = " #table(type table [myText=Text.Type, myNumber=Int64.Type, myDate=Date.Type], {{null, null, null}}) "
]}]
in
    Value.ReplaceType(func, Value.ReplaceMetadata(Value.Type(func), documentation))
in
    fnFormatted

Hi @ImkeF
Thank you for this very useful function that helps me to handle query errors and compare table schemas.
I forked it to quote the column's name to handle names containing spaces and special characters. What do you think about that?