escape.bas

100 '---緊急脱出プログラム---
110 CONSOLE 0,25,0,1
120 CLS 3
130 ON ERROR GOTO 360
140 ON KEY GOSUB 360:KEY OFF
150 ON STOP GOSUB 360:STOP OFF
160 WAITTIME=12000
170 GOSUB *HYOJI
180 FOR L=0 TO 13:PRINT:NEXT
190 LOCATE,CSRLIN-12
200 GOSUB *HYOJI
210 KEY ON:STOP ON
220 KEYSTOP=1
230 GOSUB *CURSOR
240 IF KEYSTOP=1 THEN GOTO 230
250 IF KEYSTOP=2 THEN GOTO 350
270 CLS:LOCATE 33,7:PRINT"■■■■■"
280 FOR K=0 TO 2:LOCATE 33,8+K:PRINT"■":NEXT
290 LOCATE 33,11:PRINT"■■■■"
300 FOR K=0 TO 1:LOCATE 33,12+K:PRINT"　　　　■":NEXT
310 FOR K=0 TO 1:LOCATE 33,14+K:PRINT"■　　　■":NEXT
320 LOCATE 33,16:PRINT"　■■■":COLOR 7
330 FOR L=0 TO WAITTIME*1000:NEXT
350 KEY OFF:STOP OFF
360 CONSOLE 0,25,0,0
370 CLS:PRINT:PRINT:PRINT"DEL: プログラムは消去されました。"
380 GOTO 380
400 ' ---/* 表示するサブルーチン */---
410 '    SUB Name    *HYOJI
420 '    Var Param   WAITTIME
430 '        Local   C$,K
440 ' --------------------------------
450 *HYOJI
460   FOR K=0 TO WAITTIME*8:NEXT
470   READ C$
480   IF C$="" THEN GOSUB *CURSOR:GOTO 470
490   IF C$="<BR>" THEN PRINT"　":GOTO 470
500   IF C$="<TAB>" THEN PRINT TAB(14):GOTO 470
510   IF C$="<END>" THEN RETURN
520   PRINT C$;"＿";
530   LOCATE POS(0)-2
540 GOTO 460
550 ' ---/* カーソルを点滅するサブルーチン */---
560 '    SUB Name    *CURSOR
570 '    Var Param   WAITTIME
580 '        Local   K,L
590 ' ------------------------------------------
600 *CURSOR
610 FOR L=1 TO 8
620     IF L MOD 2=0 THEN PRINT"＿"; ELSE PRINT"　";
630     LOCATE POS(0)-2
640     FOR K=0 TO WAITTIME*4
650         IF KEYSTOP=1 THEN A$=INKEY$ ELSE A$=""
660         IF A$<>"" THEN KEYSTOP=0:GOTO *ELEVATOR
670     NEXT K
680 NEXT L
690 RETURN
700 ' ---/* エレベーター */---
710 '    SUB Name    *ELEVATOR
720 '    Var Param   WAITTIME
730 '        Local   K,L
740 ' ------------------------
750 *ELEVATOR
760 KEY OFF:STOP OFF:KEYSTOP=0
770 IF ASC(A$)<>13 THEN KEYSTOP=2:RETURN
780 FOR L=0 TO 47
790     FOR K=0 TO WAITTIME*16:NEXT:CLS
800     FOR K=2 TO 13
810         LOCATE 33,K+4:COLOR 2
820         IF (L+K)MOD 12=5 OR (L+K)MOD 12>8 THEN PRINT"　　　■"
830         IF (L+K)MOD 12=6 THEN PRINT"　　■■■"
840         IF (L+K)MOD 12=7 THEN PRINT"　■　■　■"
850         IF (L+K)MOD 12=8 THEN PRINT"■　　■　　■"
860     NEXT K
870 NEXT L
880 RETURN
900 ' ---/* 文章データ */---
905 DATA "","","","","Ｙ","Ｕ","Ｋ","Ｉ","．","Ｎ","＞","","","","","こ","れ","を","あ","な","た","が","読","ん","で","い","る","時","、","<BR>"
910 DATA "<TAB>","わ","た","し","は","わ","た","し","で","は","な","い","だ","ろ","う","。","","<BR>","<BR>"
915 DATA "","","Ｙ","Ｕ","Ｋ","Ｉ","．","Ｎ","＞","こ","の","メ","ッ","セ","ー","ジ","が","表","示","さ","れ","た","と","い","う","こ","と","は","、","<BR>"
920 DATA "<TAB>","そ","こ","に","は","あ","な","た","、","わ","た","し","、","涼","宮","ハ","ル","ヒ","、","朝","比","奈","み","く","る","、","<BR>"
925 DATA "<TAB>","古","泉","一","樹","が","存","在","し","て","い","る","は","ず","で","あ","る","。","","<BR>","<BR>"
930 DATA "","","Ｙ","Ｕ","Ｋ","Ｉ","．","Ｎ","＞","そ","れ","が","鍵","。","","<BR>"
935 DATA "<TAB>","あ","な","た","は","解","答","を","見","つ","け","出","し","た","。","","<BR>","<BR>"
940 DATA "","","Ｙ","Ｕ","Ｋ","Ｉ","．","Ｎ","＞","こ","れ","は","緊","急","脱","出","プ","ロ","グ","ラ","ム","で","あ","る","。","<BR>","<BR>"
945 DATA "<TAB>","","","起","動","さ","せ","る","場","合","は","エ","ン","タ","ー","キ","ー","を","、","","<BR>"
950 DATA "<TAB>","そ","う","で","な","い","場","合","は","そ","れ","以","外","の","キ","ー","を","選","択","せ","よ","。","<END>"
955 DATA "<TAB>","","","起","動","さ","せ","た","場","合","、","<BR>"
960 DATA "<TAB>","あ","な","た","は","時","空","修","正","の","機","会","を","得","る","。","<BR>"
965 DATA "<TAB>","た","だ","し","成","功","は","保","証","で","き","な","い","。","<BR>"
970 DATA "<TAB>","ま","た","帰","還","の","保","証","も","で","き","な","い","。","","<BR>","<BR>"
975 DATA "","","Ｙ","Ｕ","Ｋ","Ｉ","．","Ｎ","＞","こ","の","プ","ロ","グ","ラ","ム","が","起","動","す","る","の","は","一","度","き","り","で","あ","る","。","<BR>"
980 DATA "<TAB>","実","行","の","の","ち","、","消","去","さ","れ","る","。","<BR>","<BR>"
985 DATA "<TAB>","非","実","行","が","選","択","さ","れ","た","場","合","は","起","動","せ","ず","に","消","去","さ","れ","る","。","<BR>","<BR>"
990 DATA "<TAB>","","Ｒ","ｅ","ａ","ｄ","ｙ","？","<END>"