Patch to fix WayBar-git aur package at the 01.09.2022 (this file will not be available indefinitly probably)

PKGBUILD

# Maintainer: Alexis Rouillard <contact@arouillard.fr>

pkgname=waybar-git
pkgver=r2125.ac193ae
pkgrel=1
pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors (GIT)'
arch=('x86_64')
url='https://github.com/Alexays/Waybar/'
license=('MIT')
provides=('waybar')
conflicts=('waybar')
depends=(
    'gtkmm3'
    'libjsoncpp.so'
    'libinput'
    'libsigc++'
    'fmt'
    'wayland'
    'chrono-date'
    'libspdlog.so'
    'gtk-layer-shell'
    'libpulse'
    'libnl'
    'libappindicator-gtk3'
    'libdbusmenu-gtk3'
    'libmpdclient'
)
makedepends=(
    'git'
    'cmake'
    'meson'
    'scdoc' # For generating manpages
    'wayland-protocols'
)
optdepends=(
    'otf-font-awesome: Icons in the default configuration'
)

source=(
    "${pkgname}::git+https://github.com/Alexays/Waybar"
    "https://gist.githubusercontent.com/JBenda/934a62398e0d1e7a775eeea47385fff2/raw/191b4948a890c7f8e03bfc29133a2ff06a460707/WayBarFmtHotFix.patch"
)

sha1sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "${srcdir}/${pkgname}"
    patch --strip=1 --input=${srcdir}/WayBarFmtHotFix.patch
}

build() {
    cd "${srcdir}/${pkgname}"
    rm -rf "${srcdir}/build"
    meson --prefix=/usr "${srcdir}/build"
    ninja -C "${srcdir}/build"
}

package() {
    DESTDIR="$pkgdir" ninja -C "${srcdir}/build" install
}
sha1sums=('SKIP'
          '96e09e19be1f7975139ae66b6f8d7a24503234f7')

WayBarFmtHotFix.patch

diff --color --unified --recursive --text package.old/src/config.cpp package.new/src/config.cpp
--- package.old/src/config.cpp	2022-09-07 10:15:59.754998091 +0200
+++ package.new/src/config.cpp	2022-09-07 10:16:23.621777055 +0200
@@ -30,14 +30,14 @@
     path = fs::path(base);
   }
 
-  spdlog::debug("Try expanding: {}", path);
+  spdlog::debug("Try expanding: {}", path.string());
 
   wordexp_t p;
   if (wordexp(path.c_str(), &p, 0) == 0) {
     if (access(*p.we_wordv, F_OK) == 0) {
       std::string result = *p.we_wordv;
       wordfree(&p);
-      spdlog::debug("Found config file: {}", path);
+      spdlog::debug("Found config file: {}", path.string());
       return result;
     }
     wordfree(&p);