Deep compare 2 JavaScript objects

compare.coffee

compare = (->
  compareByType =
    "array": (a, b) ->
      return false if a.length isnt b.length
      return false for i in [0...a.length] when not equals a[i], b[i]
      true

    "object": (a, b) ->
      return false for i of a when not (b.hasOwnProperty i) or not equals a[i], b[i]
      return false for i of b when not a.hasOwnProperty i
      true

    "date": (a, b) ->
      a.getTime() is b.getTime()

    "regexp": (a, b) ->
      a.toString() is b.toString()

    "function": (a, b) ->
      compareByType["regexp"] a, b

  getType = (val) ->
    return "undefined" if val is undefined
    return "null" if val is null
    type = typeof val
    switch type
      when "object"
        type = (Object::toString.call val).match(/^\[object\s(.*)\]$/)[1].toLowerCase()
      when "number"
        type = if (val.toString().indexOf ".") > 0 then "float" else "integer"
    type

  equals = (a, b) ->
    return true if a is b
    aType = getType a
    bType = getType b
    return false if aType isnt bType
    if compareByType.hasOwnProperty aType then compareByType[aType] a, b else `a == b`

  equals
)()