Utility to show things without Show instance (but Data instance)

GenericShow.hs

{-# LANGUAGE AllowAmbiguousTypes #-}
{-# LANGUAGE MonadComprehensions #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeApplications #-}
{-# LANGUAGE DeriveDataTypeable #-}

import Data.Data
import Data.Foldable
import Data.Functor
import Data.Maybe
import Data.List

genericShow :: forall a . Data a => a -> String
genericShow a = catchAll `fromMaybe` asum [tryShow @String]
  where
    tryShow :: forall e . (Show e, Typeable e) => Maybe String
    tryShow = cast @_ @e a <&> show
    catchAll :: String
    catchAll | null rest = ctr
             | otherwise = "(" <> intercalate " " (ctr : rest) <> ")"
      where rest = gmapQ genericShow a
            ctr = show (toConstr a)

data Example = Node String Int Char Example
             | Empty
             deriving Data

main :: IO ()
main = putStrLn . genericShow $ Node "foo" 1 'a' $ Node "bar" 42 'b' Empty

-- Output:
-- (Node "foo" 1 'a' (Node "bar" 42 'b' Empty))