ColdFusion / CFML UDF to determine if request/content has been flushed using CFFlush or by exceeding max buffer.

isFlushed.cfm

<cfscript>
/* 20200121 ColdFusion / CFML UDF to determine if request/content has been flushed using CFFlush or by exceeding max buffer. */
boolean function isFlushed(){
	var response = false;
	var headers = {};
	if (StructKeyExists(request, "isFlushedAlready") AND isValid("boolean", request.isFlushedAlready) and request.isFlushedAlready){
		return true;
	}
	headers = GetHttpRequestData(false).headers;
	if (StructKeyExists(headers, "Expect") or not len(CGI.HTTP_Connection)){
		response = true;
	} else if (StructKeyExists(Server, "lucee")){
		response = getPageContext().getHttpServletResponse().isCommitted() or getPageContext().getHttpServletResponse().isTreatAsCommitted();
	} else {
		response = getPageContext().getResponse().isCommitted() or getPageContext().getFusionContext().getResponse().isOutputAutoFlushed();
	}
	request.isFlushedAlready = response;
	return response;
}
</cfscript>