link-classpath.gradle.kts

// The following task would create a `classpath` directory under the build dir, with a copy of the built jar and links of every jar from classpath.
// You can start the project by `java -classpath "classpath/*" MainClass`.
// This is useful for creating a personal-used script reusing gradle cache.
// This idea is inspired by the pnpm project.
task("linkClasspath") {
    val jarTask = tasks.getByName("jar", Jar::class)
    dependsOn(jarTask)
    doLast {
        val targetDir = File(buildDir, "classpath")
        if (!targetDir.mkdirs()) {
            targetDir.walkBottomUp().forEach { file ->
                if (file != targetDir) {
                    if (!file.delete()) {
                        throw Exception("unable to delete old file `$file`")
                    }
                }
            }
        }

        sourceSets["main"]
            .runtimeClasspath
            .filter { it.isFile }
            .forEach { file ->
                println(file.absolutePath)
                Files.createLink(File(targetDir, file.name).toPath(), file.toPath())
            }

        val jarName = jarTask.archiveFileName.get()
        Files.copy(Paths.get(buildDir.path, "libs", jarName), File(targetDir, jarName).toPath())
    }
}