CLJS run single test var

cljs.test.repl.clj

(ns cljs.test.repl
  (:require [cljs.analyzer.api :as ana-api]
            [cljs.analyzer :as ana]
            [cljs.test]))

(defmacro run-single-test [[quote var :as form]]
  (let [ns (or (some-> var namespace symbol)
               ana/*cljs-ns*)]
    `(cljs.test/run-block
      (concat
       [(fn []
          (cljs.test/set-env! (cljs.test/empty-env))
          ~(when (ana-api/ns-resolve ns 'cljs-test-once-fixtures)
             `(cljs.test/update-current-env! [:once-fixtures] assoc '~ns
                                             ~(symbol (name ns) "cljs-test-once-fixtures")))
          ~(when (ana-api/ns-resolve ns 'cljs-test-each-fixtures)
             `(cljs.test/update-current-env! [:each-fixtures] assoc '~ns
                                             ~(symbol (name ns) "cljs-test-each-fixtures"))))]
       (cljs.test/test-vars-block [~form])
       [(fn []
          (cljs.test/report (merge (:report-counters (cljs.test/get-current-env))
                                   {:type :summary :ns ~ns}))
          (cljs.test/clear-env!))]))))