Arma 3 ACE Arsenal classnameArray

leftPanelClassnames.sqf

["ace_arsenal_leftPanelFilled", {

   params ["_display"];
   private _control = _display displayCtrl 13;

   "ace_clipboard" callExtension "[";

   for "_lbIndex" from 0 to (lbSize _control - 1) do {

       private _currentData = _control lbData _lbIndex;
       if (_lbIndex == lbSize _control - 1) then {
            "ace_clipboard" callExtension format ["%1 %2", str _currentData, endl];
        } else {
            "ace_clipboard" callExtension format ["%1,%2", str _currentData, endl];
        };
   };

   "ace_clipboard" callExtension "];";
   "ace_clipboard" callExtension "--COMPLETE--";

}] call CBA_fnc_addEventHandler;

rightPanelClassnames.sqf

["ace_arsenal_rightPanelFilled", {

    params ["_display"];
    "ace_clipboard" callExtension "[";

    if (ace_arsenal_currentLeftPanel in [2010, 2012, 2014]) then {

        private _control = _display displayCtrl 15;
        private _lnbSize = (lnbSize _control) select 0;

        for "_lnbIndex" from 0 to (_lnbSize - 1) do {

            private _currentData = _control lnbData [_lnbIndex, 0];
            if (_lnbIndex ==  _lnbSize - 1) then {
                "ace_clipboard" callExtension format ["%1 %2", str _currentData, endl];
            } else {
                "ace_clipboard" callExtension format ["%1,%2", str _currentData, endl];
            };
        };
    } else {

        private _control = _display displayCtrl 14;
        for "_lbIndex" from 0 to (lbSize _control - 1) do {

            private _currentData = _control lbData _lbIndex;
            if (_lbIndex == lbSize _control - 1) then {
                "ace_clipboard" callExtension format ["%1 %2", str _currentData, endl];
            } else {
                "ace_clipboard" callExtension format ["%1,%2", str _currentData, endl];
            };
        };
    };
    "ace_clipboard" callExtension "];";
    "ace_clipboard" callExtension "--COMPLETE--";

}] call CBA_fnc_addEventHandler;