pixelmon.zs

print("Loading pixelmon recipes!");

// Setup disc -> base recipes
val iron_disc = <pixelmon:iron_disc>;
val iron_base = <pixelmon:iron_base>;
recipes.addShaped(iron_base, [
    [iron_disc, null, iron_disc],
    [iron_disc, iron_disc, iron_disc],
]);

val aluminum_disc = <pixelmon:aluminum_disc>;
val aluminum_base = <pixelmon:aluminum_base>;
recipes.addShaped(aluminum_base, [
    [aluminum_disc, null, aluminum_disc],
    [aluminum_disc, aluminum_disc, aluminum_disc],
]);

val ball_base = <ore:poke_base>;

val iron_ingot = <ore:ingotIron>;
val aluminum_plate = <pixelmon:aluminium_plate>;
recipes.addShaped(aluminum_plate, [
    [iron_ingot, iron_ingot, iron_ingot]
]);

// Add entries to ore dictionary
<ore:plateAluminum>.add(aluminum_plate);
ball_base.add(aluminum_base);
ball_base.add(iron_base);

// Add master ball recipe
val ender_star = <actuallyadditions:item_misc:19>;
val magenta_matter = <projectex:matter:0>;
val wyvern_core = <draconicevolution:wyvern_core>;
val infused_obsidian = <draconicevolution:infused_obsidian>;
recipes.addShaped(<pixelmon:master_ball>, [
    [magenta_matter, magenta_matter, magenta_matter],
    [wyvern_core, ender_star, wyvern_core],
    [infused_obsidian, infused_obsidian, infused_obsidian]
]);

// Setup disc -> lid -> ball recipes
val ball_types as string[] = [
    "poke_ball",
    "great_ball",
    "ultra_ball",
    "level_ball",
    "moon_ball",
    "friend_ball",
    "love_ball",
    "safari_ball",
    "heavy_ball",
    "fast_ball",
    "repeat_ball",
    "timer_ball",
    "nest_ball",
    "net_ball",
    "dive_ball",
    "luxury_ball",
    "heal_ball",
    "dusk_ball",
    "premier_ball",
    "sport_ball",
    "quick_ball",
    "lure_ball",
];

val poke_ball = <pixelmon:poke_ball>;

for ball_type in ball_types {
    var ball = itemUtils.getItem("pixelmon:" + ball_type);
    var disc = itemUtils.getItem("pixelmon:" + ball_type + "_disc");
    var lid = itemUtils.getItem("pixelmon:" + ball_type + "_lid");

    // load ball crafting recipes

    recipes.addShaped(lid, [
        [disc, disc, disc],
        [disc, null, disc],
    ]);

    recipes.remove(ball);
    recipes.addShaped(ball, [
        [lid],
        [<minecraft:stone_button>],
        [ball_base]
    ]);

    if(ball_type != "poke_ball"){
        recipes.addShaped(ball, [
            [lid],
            [poke_ball]
        ]);
    }
}
print("Finished loading pixelmon recipes!");