YAML sample with Groovy 3

1_yaml_slurper_sample.groovy

import groovy.yaml.YamlSlurper

def slurper = new YamlSlurper()

def configuration = '''
version: 3.0
environment: "dev"
context:
  path: "/test"
endpoints:
  url: "/people"
  operations:
    POST: "create"
    GET: "list or get"
    PUT: "/update"
    DELETE: "delete"
'''

def yaml = slurper.parseText(configuration)

println "YAML keys: ${yaml.keySet()}"

yaml.keySet().each { key ->
   println "Key: $key \t Type: ${yaml[key].getClass().name}"
}

2_yaml_builder_sample.groovy

import groovy.yaml.YamlBuilder

def yaml = new YamlBuilder()

yaml {
  version 3.0
  environment "dev"
  context {
    path "/test"
  }
  endpoints {
    url "/people"
    operations ("POST":"create", "GET":"list or get", "PUT":"update", "DELETE":"delete")
  }
}

println yaml

3_yaml_builder_from_map.groovy

import groovy.yaml.YamlBuilder

Map configuration = [
  version : 3.0,
  environment : "dev",
  context : [path:"/test"],
  endpoints : [url:"/people",
    operations: [POST:"create", GET:"list or get",
                 PUT:"update", DELETE:"delete"]
  ]
]

def yaml = new YamlBuilder()

yaml(configuration)

println yaml

4_yaml_builder_from_object.groovy

import groovy.yaml.YamlBuilder

class Configuration {
   BigDecimal version
   String environment
   Map context
   Map endpoints
}

def configuration = new Configuration()

configuration.with{
  version = 3.0
  environment = "dev"
  context = [path:"/test"]
  endpoints = [url:"/people",
    operations: [POST:"create", GET:"list or get",
                 PUT:"update", DELETE:"delete"]
  ]
}

def yaml = new YamlBuilder()

yaml(configuration)

println yaml