Open GUI application / file from Vim in background

start-open.vim

" To start the GUI app, use :Silent! app
" Useful, say, to look up a keyword by :set keywordprg=:Silent!\ zeal

" To open file, use :Open! file
" Useful, say, to view a compiled HTML of a markdown file, by :Open! %:r.html

if executable('cmd.exe') " Win32 or WSL
  command! -complete=shellcmd -nargs=1 -bang Silent
        \ execute ':silent !' .
        \ (&shell =~? '\v(^|\\)cmd\.exe$' ? '' : 'cmd.exe /c ') .
        \ (<bang>0 ? 'start /b ' : '') . <q-args> | execute ':redraw!'
elseif has('unix')
  command! -complete=shellcmd -nargs=1 -bang Silent execute ':silent !' .
        \ (<bang>0 ? 'nohup ' . <q-args> . ' </dev/null >/dev/null 2>&1 &' : <q-args>) | execute ':redraw!'
endif
command! -complete=shellcmd -nargs=1 -bang Sil    Silent<bang> <args>

" Windows / Git Bash / WSL
if executable('cmd.exe')
    let s:cmd = "explorer.exe"
" Linux/BSD
elseif executable("xdg-open")
    let s:cmd = "xdg-open"
" MacOS
elseif executable("open")
    let s:cmd = "open"
endif
exe 'command! -complete=file -nargs=1 -bang Open exe "Silent<bang> ' . s:cmd . ' " . shellescape(<q-args>)'