fn-called simple mocking

fn_called.clj

(ns clj-demgen.util.fn-called
  (:require [clojure.test :as t :refer [is deftest]]))


(defn fn-called? [f thunk]
  (let [called (atom false)]
    (with-redefs-fn {f (fn [& args]
                         (reset! called true))}
      thunk)
    @called))

(defmacro is-fn-called? [f & body]
  `(is (fn-called? ~(resolve f)
                   (fn [] ~@body))
       ~(str "Function `" f "` not called")))

(defn fn-called-with-args? [f thunk checks-thunk]
  (let [called (atom false)
        f-args (atom [])]
    (with-redefs-fn {f (fn [& args]
                         (reset! called true)
                         (reset! f-args args))}
      thunk)
    (if @called
      (apply checks-thunk @f-args))
    @called))

(defmacro is-fn-called-with-args? [f args arg-checks & body]
  `(is (fn-called-with-args? ~(resolve f)
                             (fn [] ~@body)
                             (fn ~args ~@arg-checks))
       ~(str "Function `" f "` not called")))

(defn log [s]
  (println s))

#_(deftest fn-called-test
    (is-fn-called? log (log "Foo")))


#_(deftest fn-called-with-args-test
    (is-fn-called-with-args? log
                             [s]
                             [(is (= s "Bar?"))]
                             (log "Foo!")))