https://stackoverflow.com/questions/56349611/generically-determining-arity-of-data-types

Arity.hs

{-# LANGUAGE
    AllowAmbiguousTypes,
    ScopedTypeVariables,
    TypeApplications,
    TypeFamilies,
    UndecidableInstances,
    FlexibleContexts,
    DataKinds,
    DeriveGeneric,
    TypeOperators
  #-}

import Data.Kind (Type)
import Data.Proxy
import Numeric.Natural
import GHC.Generics
import GHC.TypeNats

type family Arity (f :: Type -> Type) :: Nat
type instance Arity (M1 i c f) = Arity f
type instance Arity (f :*: g) = Arity f + Arity g
type instance Arity U1 = 0
type instance Arity (K1 i a) = 1

arity :: forall a. (Generic a, KnownNat (Arity (Rep a))) => Natural
arity = natVal (Proxy @(Arity (Rep a)))

data T = T Int Bool String
  deriving Generic

main = print (arity @T)  -- 3

The type errors will be horrible. You can fix that using something like this:

type family Arity (x :: Type) (f :: Type -> Type) :: Nat
type instance Arity x (M1 i c f) = Arity x f
type instance Arity x (f :*: g) = Arity x f + Arity x g
type instance Arity _ U1 = 0
type instance Arity _ (K1 i a) = 1
type instance Arity x (_ :+: _) =
  TypeError ('Text "Cannot calculate the arity of "
             :<>: 'ShowType x
             :<>: 'Text " because it has multiple constructors.")
type instance Arity x V1 =
  TypeError ('Text "Cannot calculate the arity of "
             :<>: 'ShowType x
             :<>: 'Text " because it has no constructors.")

arity :: forall a. (Generic a, KnownNat (Arity a (Rep a))) => Natural