Quantified constraint trick https://blog.poisson.chat/posts/2022-09-21-quantified-constraint-trick.html

DG.hs

{-# LANGUAGE
    ConstraintKinds,
    FlexibleContexts,
    FlexibleInstances,
    MultiParamTypeClasses,
    QuantifiedConstraints,
    RankNTypes,
    ScopedTypeVariables,
    TypeApplications,
    UndecidableInstances #-}
{-# OPTIONS_GHC -Wno-simplifiable-class-constraints #-}
module DG where

import GHC.Generics

class RepFmap a a' rep rep' where
  repFmap :: (a -> a') -> rep -> rep'

gfmap :: forall f a a'. GFunctor f => (a -> a') -> f a -> f a'
gfmap f =
  with @(RepFmapRep a a' f)             -- Hand-holding for GHC <= 9.0
    (to @_ @() . repFmap f . from @_ @())

with :: forall c r. (c => r) -> (c => r)
with x = x

class    (forall a. Generic (f a), forall a a'. RepFmapRep a a' f) => GFunctor f
instance (forall a. Generic (f a), forall a a'. RepFmapRep a a' f) => GFunctor f

class    RepFmap a a' (Rep (f a) ()) (Rep (f a') ()) => RepFmapRep a a' f
instance RepFmap a a' (Rep (f a) ()) (Rep (f a') ()) => RepFmapRep a a' f