public
Created

  • Download Gist
smart_ptr.d
D
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287
import std.traits;
import core.memory;
 
struct Ptr(T)
{
static if (is(T == class))
alias T RefT;
else
alias T* RefT;
 
this(RefT p, void function(RefT) deleter)
{
_ptr = p;
del = deleter;
}
 
private this(RefT ptr, ControlBlock *cb)
{
_ptr = ptr;
this.cb = cb;
}
 
// copying requires explicit usage of .release or .dup
@disable this(this);
 
@property Ptr dup()
{
ControlBlock* p = void;
if ((p = cb) !is null)
++p._count;
else
cb = p = alloc!ControlBlock(2, del);
return Ptr(_ptr, p);
}
 
@property Ptr release()
{
import std.algorithm;
return move(this);
}
 
// rvalue assign
void opAssign(Ptr other)
{
import std.algorithm;
move(other, this);
}
 
~this()
{
if (auto p = cb)
{
if (!--p._count)
{
p._del(_ptr);
dealloc!ControlBlock(p);
}
}
else if (auto fn = del)
fn(_ptr);
else
assert(this is Ptr.init);
}
 
static if (is(T == class))
{
@property inout(T) get() inout
{
return _ptr;
}
}
else
{
@property ref inout(T) get() inout
{
return *_ptr;
}
}
 
alias get this;
 
@property bool unique() const pure nothrow
{
return count == 1;
}
 
@property size_t count() const pure nothrow
{
if (auto p = cb)
return p._count;
else
return del is null ? 0 : 1;
}
 
private:
@property inout(void function(RefT)) del() inout pure nothrow
{
return (cast(size_t)_pcb & 0x1) ?
cast(typeof(return))(cast(size_t)_pcb & ~cast(size_t)0x1) :
null;
}
 
@property void del(void function(RefT) val) pure nothrow
{
_pcb = cast(void*)(cast(size_t)val | 0x1);
}
 
@property inout(ControlBlock)* cb() inout pure nothrow
{
return (cast(size_t)_pcb & 0x1) ? null : cast(typeof(return))_pcb;
}
 
@property void cb(ControlBlock* val) pure nothrow
{
assert(!(cast(size_t)val & 0x1));
_pcb = val;
}
 
struct ControlBlock
{
size_t _count;
void function(RefT) _del;
}
 
RefT _ptr;
void* _pcb;
}
 
/**
*
*/
Ptr!(T) make(T, Args...)(Args args)
{
return Ptr!T(alloc!T(args), &dealloc!T);
}
 
private:
 
auto alloc(T, Args...)(auto ref Args args)
{
import core.stdc.stdlib, std.conv;
 
static if(is(T == class))
enum sz = __traits(classInstanceSize, T);
else
enum sz = T.sizeof;
auto chunk = malloc(sz)[0 .. sz];
static if (hasAliasing!T)
GC.addRange(chunk.ptr, sz);
return emplace!T(chunk, args);
}
 
void dealloc(T)(T p) if(is(T == class))
{
import core.stdc.stdlib;
if (p !is null)
{
clear(p);
static if (hasAliasing!T)
GC.removeRange(cast(void*)p);
free(cast(void*)p);
}
}
 
void dealloc(T)(T* p) if(!is(T == class))
{
import core.stdc.stdlib;
if (p !is null)
{
clear(*p);
static if (hasAliasing!T)
GC.removeRange(cast(void*)p);
free(cast(void*)p);
}
}
 
unittest
{
Ptr!int p1;
assert(!p1.count);
assert(!p1.unique);
Ptr!int p2 = make!int();
assert(p2.count == 1);
assert(p2.unique);
p1 = p2.dup;
assert(p1.get is p2.get);
assert(p1.count == 2);
assert(p2.count == 2);
 
auto p3 = p2.dup;
}
 
version (unittest)
{
struct S
{
this(int val=0)
{
_val = val;
++_n;
}
 
~this()
{
--_n;
}
 
int _val;
static size_t _n;
}
 
class C
{
this(int val=0)
{
_val = val;
++_n;
}
 
~this()
{
--_n;
}
 
int _val;
static size_t _n;
}
}
 
unittest
{
import std.typetuple;
 
static Ptr!T foo(T)(Ptr!T p)
{
assert(p.unique);
return p.release;
}
 
static Ptr!T bar(T)(Ptr!T p)
{
assert(!p.unique);
return p.dup;
}
 
foreach(T; TypeTuple!(S, C))
{
{
scope (success) assert(T._n == 0);
 
auto ptr1 = make!T(0);
assert(ptr1.count == 1);
ptr1 = foo(ptr1.release);
assert(ptr1.count == 1);
auto ptr2 = foo(ptr1.release);
assert(ptr2.unique);
assert(ptr1.count == 0);
}
 
{
scope (success) assert(T._n == 0);
 
auto ptr1 = make!T(0);
ptr1 = bar(ptr1.dup);
assert(ptr1.unique);
auto ptr2 = bar(ptr1.dup);
assert(ptr1.get == ptr2.get);
assert(ptr1.count == 2);
assert(ptr2.count == 2);
}
 
{
scope (success) assert(T._n == 0);
 
Ptr!T p1, p2;
static assert(!__traits(compiles, p1 = p2));
p1 = make!T(1);
p2 = make!T(2);
assert(p1._val == 1);
assert(p2._val == 2);
import std.algorithm;
swap(p1, p2);
assert(p1._val == 2);
assert(p2._val == 1);
}
}
}

Please sign in to comment on this gist.

Something went wrong with that request. Please try again.