slide min

model.stan

functions {
  vector slide_min(int I, int K, vector x) {
    vector[I-K+1] res;
    int deq[I];
    int s;
    int t;
    s = 1;
    t = 1;
    for (i in 1:I) {
      while (s < t && x[deq[t-1]] >= x[i])
        t = t-1;
      deq[t] = i;
      t = t+1;
      if (i-K+1 >= 1) {
        res[i-K+1] = x[deq[s]];
        if (deq[s] == i-K+1)
          s = s+1;
      }
    }
    return res;
  }
}

data {
  int I;
  int I_obs;
  int I_mis;
  int Idx_obs[I_obs];
  int Idx_mis[I_mis];
  vector[I_obs] X_obs;
  int K;
  vector[I-K+1] Y;
}

parameters {
  vector[I_mis] x_mis;
  real<lower=0> s_y;
}

transformed parameters {
  vector[I-K+1] mu;
  {
    vector[I] x;
    for (i in 1:I_obs) x[Idx_obs[i]] = X_obs[i];
    for (i in 1:I_mis) x[Idx_mis[i]] = x_mis[i];
    mu = slide_min(I, K, x);
  }
}

model {
  x_mis ~ normal(0, 5);
  Y ~ normal(mu, s_y);
}

run-model.R

library(rstan)

stanmodel <- stan_model(file='model.stan')

d <- read.csv(file='z-data.csv')
I <- 100
K <- 8
Idx_obs <- which(!is.na(d$X_obs))
Idx_mis <- setdiff(seq_len(I), Idx_obs)
I_obs <- length(Idx_obs)
I_mis <- I - I_obs
X_obs <- d$X_obs[Idx_obs]
Y <- d$Y[1:(I-K+1)]

data <- list(I=I, I_obs=I_obs, I_mis=I_mis, Idx_obs=Idx_obs, Idx_mis=Idx_mis, X_obs=X_obs, K=K, Y=Y)
fit <- sampling(stanmodel, pars=c('x_mis', 's_y'), data=data, seed=123)

z-data.csv