Playing with FASTA parsing

fasta.p6

#!/usr/bin/env perl6
use v6;

class Bio::Sequence {
    has Str $.id = "";
    has Str $.comment = "";
    has Str $.sequence = "";
}

class Bio::Sequence::Amino is Bio::Sequence {

}

class Bio::Actions::FASTA {
    method TOP($/) {
        make $<record>>>.ast;
    }
    method record($/) {
        given ~$<sequence><sym> {
            when "aa" {
                make Bio::Sequence::Amino.new(
                    id => ~$<id>,
                    comment => ~$<comment>,
                    sequence => ~$<sequence>.subst("\n","", :g)
                );
            }
            default {
                make Bio::Sequence.new(
                    id => ~$<id>,
                    comment => ~$<comment>,
                    sequence => ~$<sequence>.subst("\n","", :g)
                );
            }
        }
    }
}

grammar Bio::Grammar::FASTA {
    token TOP {
        <record>+
    }

    token record {
        ">"<id>" "<comment>"\n"<sequence>
    }

    token id {
        <-[\ ]>+
    }
    token comment {
        <-[\n]>+
    }

    proto token sequence {*}
    token sequence:sym<aa> {
        <[A..Z\*\-\n]>+
    }
    token sequence:sym<dna> {
        <[ACGTRYKMSWBDHVNX\-\n]>+
    }
    token sequence:sym<rna> {
        <[ACGURYKMSWBDHVNX\-\n]>+
    }

}

my $sequences = slurp "test.fa";
my $results = Bio::Grammar::FASTA.parse( $sequences, actions => Bio::Actions::FASTA.new() ).ast;
say $results.perl;

You may want something more like:

method record($/) {
    make $<sequence>.ast.new(
        id => ~$<id>,
        comment => ~$<comment>,
        sequence => $<sequence>.subst("\n","", :g) # [aside: ~$<s…>.subst(…) means ~($<s…>.subst(…))]
    );
}
# "sequence:sym<aa>" works just as well as "sequence:aa" as long
# as they're named the same in the grammar and actions :)
method sequence:aa  ($/) { make Bio::Sequence::Amino }
method sequence:dna ($/) { make Bio::Sequence }
method sequence:rna ($/) { make Bio::Sequence }

Hope that's helpful ^_^