Metal FXAA anti-aliasing

fxaa.metal

#include <metal_stdlib>
using namespace metal;
#include <CoreImage/CoreImage.h>

extern "C" {

    namespace coreimage {

        static float4 textureAtLocation(sampler s, float2 c) {
            return s.sample(c / s.size());
        }

        float4 fxaa(sampler s) {
            float2 fragCoord = s.coord() * s.size();
            float2 v_rgbNW = (fragCoord + float2(-1.0, -1.0));
            float2 v_rgbNE = (fragCoord + float2(1.0, -1.0));
            float2 v_rgbSW = (fragCoord + float2(-1.0, 1.0));
            float2 v_rgbSE = (fragCoord + float2(1.0, 1.0));
            float2 v_rgbM = fragCoord;

            const float FXAA_REDUCE_MIN = (1.0/ 128.0);
            const float FXAA_REDUCE_MUL = (1.0 / 8.0);
            const float FXAA_SPAN_MAX = 8.0;

            float4 color;
            float3 rgbNW = textureAtLocation(s, v_rgbNW).xyz;
            float3 rgbNE = textureAtLocation(s, v_rgbNE).xyz;
            float3 rgbSW = textureAtLocation(s, v_rgbSW).xyz;
            float3 rgbSE = textureAtLocation(s, v_rgbSE).xyz;
            float4 texColor = textureAtLocation(s, v_rgbM);
            float3 rgbM  = texColor.xyz;
            float3 luma = float3(0.299, 0.587, 0.114);
            float lumaNW = dot(rgbNW, luma);
            float lumaNE = dot(rgbNE, luma);
            float lumaSW = dot(rgbSW, luma);
            float lumaSE = dot(rgbSE, luma);
            float lumaM  = dot(rgbM,  luma);
            float lumaMin = min(lumaM, min(min(lumaNW, lumaNE), min(lumaSW, lumaSE)));
            float lumaMax = max(lumaM, max(max(lumaNW, lumaNE), max(lumaSW, lumaSE)));

            float2 dir;
            dir.x = -((lumaNW + lumaNE) - (lumaSW + lumaSE));
            dir.y =  ((lumaNW + lumaSW) - (lumaNE + lumaSE));

            float dirReduce = max((lumaNW + lumaNE + lumaSW + lumaSE) *
                                  (0.25 * FXAA_REDUCE_MUL), FXAA_REDUCE_MIN);

            float rcpDirMin = 1.0 / (min(abs(dir.x), abs(dir.y)) + dirReduce);
            dir = min(float2(FXAA_SPAN_MAX, FXAA_SPAN_MAX),
                      max(float2(-FXAA_SPAN_MAX, -FXAA_SPAN_MAX),
                          dir * rcpDirMin));

            float3 rgbA = 0.5 * (textureAtLocation(s, fragCoord + dir * (1.0 / 3.0 - 0.5)).xyz + textureAtLocation(s, fragCoord + dir * (2.0 / 3.0 - 0.5)).xyz);

            float3 rgbB = rgbA * 0.5 + 0.25 * (textureAtLocation(s, fragCoord + dir * -0.5).xyz + textureAtLocation(s, fragCoord + dir * 0.5).xyz);

            float lumaB = dot(rgbB, luma);
            if ((lumaB < lumaMin) || (lumaB > lumaMax))
                color = float4(rgbA, texColor.a);
            else
                color = float4(rgbB, texColor.a);
            return color;
        }
    }
}