gistfile1.txt

configurations {
    compileGwt
}

jar {
    from {
        compileGwt.buildDir
    }

    // Exclude GWT client code and resources
    rootSpec.exclude('nl')
}

dependencies {
    compile 'com.google.guava:guava-gwt'

    // Compile GWT libs, needed for compileGwt and the javaCompile
    // Also includes the servlet-api
    compileOnly 'com.google.gwt:gwt-user'
    compileGwt 'com.google.gwt:gwt-dev'
}

task compileGwt (dependsOn: classes, type: JavaExec) {
    ext.buildDir = "${project.buildDir}/gwt"
    ext.extraDir = "${project.buildDir}/extra"

    classpath {
        [
                configurations.compileGwt,
                sourceSets.main.java.srcDirs,           // Java source
                sourceSets.main.output.resourcesDir,    // Generated resources
                sourceSets.main.output.classesDir,      // Generated classes
                sourceSets.main.compileClasspath,       // Deps
        ]
    }

    inputs.files classpath
    outputs.dir buildDir

    // Workaround input change detection (GRADLE-3528), fixed after Gradle 3.0
    def iter = environment.iterator()
    while(iter.hasNext()) {
        def entry = iter.next()
        if (entry.key =~ /APP_NAME_\d+|APP_ICON_\d+|JAVA_MAIN_CLASS_\d+/) {
            iter.remove()
        }
    }

    doFirst {
        file(buildDir).mkdirs()
    }

    main = 'com.google.gwt.dev.Compiler'

    def cpus = System.properties['gwt.cpus']?:2

    def arguments =
            [
                    'nl.my.MailClass',
                    '-war', buildDir,
                    '-logLevel', 'INFO',
                    '-localWorkers', cpus,
                    '-compileReport',
                    '-extra', extraDir,
                    '-strict'
            ]

    args = arguments

    maxHeapSize = '512M'
}

jar.dependsOn compileGwt