Clojure macro for regex that returns named capture groups as a map

named_regex.clj

(defmacro mk-named-regex-fn
  "Given an expression that returns a string returns a function
  that given a string returns nil if pattern did not match
  and a map of named groups if pattern matches.
  
  Usage: ((regex \"(?<name>[a-zA-Z]+)\") \"John\") => {\"name\" \"John\"}"
  [regex-string-expression]
  (let [regex-string (eval regex-string-expression)
        re-group-regex #"(?<!\\)(?:\\\\)*\((?:\?<(\w+)>|[^?])"
        pattern (re-pattern regex-string)
        group-names (mapv second (re-seq re-group-regex regex-string))
        group-length (count group-names)]
    `(fn [s#]
       (let [matcher# (re-matcher ~pattern s#)]
         (if (.matches matcher#)
           (loop [groups# (transient {})
                  n# 0]
             (if (< n# ~group-length)
               (let [inc-n# (inc n#)
                     group-name# (get ~group-names n#)]
                 (recur (assoc! groups# group-name# (.group matcher# inc-n#))
                        inc-n#))
               (persistent! groups#)))
           nil)))))