gistfile1.pl

use v6;

grammar UnixPath {
    token TOP { ^ [<context> '/']? (<name>|<glob>) +%% '/' $ }
    proto token context {*}
    token context:sym<~> { <sym> <?[/]> }
    token context:sym</> { <?[/]> }
    token name { <-[ * / ]>+ }
    token glob { $<initial>=['*'?] [<name> '*']+ <final=.name>? }
}
class ExpandPath {
    method TOP($/) {
        my @ex = ~$<context>;
        for @() {
            if .keys eq 'name' {
                @ex .= map: *~'/'~$_.values[0]
            }
            elsif .keys eq 'glob' {
                @ex .= map: ->\so_far{
                    (so_far ~ '/') <<~<< dir(so_far).grep($_.values[0].ast)
                }
            }
        }
        make @ex;
    }
    method context:sym<~>($/) { make qx[echo ~].chomp ~ '/' }
    method glob ($/) {
        # make regex that matches possible files/directories
        my $regex = $<initial> ?? rx/.*/ !! rx/''/;
        for $<name> {
            $regex = rx/<$regex> $_ .*/;
        }
        $regex = rx/<$regex> $_/ for $<final>;
        make $regex
    }
}

.say for UnixPath.parse(:actions(ExpandPath), '/usr/bin').ast