DDLC+ Get Ghost Startup.ahk

#Requires AutoHotkey v2.0
#SingleInstance Force

/*
  DDLC+ Get Ghost Startup
  While in Act 2, there is a 1/64 (1.53%) chance of a grayscale version of the game menu screen showing up when you open DDLC
  from the Metaverse Desktop. (https://doki-doki-literature-club.fandom.com/wiki/Easter_Eggs)
  This special occurance is very rare and is required for 100% completion, so this AutoHotkey script was created to automatically
  open and close DDLC until this occurrence shows up or until CTRL + K is pressed.

  Note: This script requires that the DDLC+ window resolution to be set to 1280x720
*/

^k::ExitApp

#HotIf WinActive("Doki Doki Literature Club Plus")
^j::
{
	Attempts := 0

	Loop {
		Attempts++

		; Press "DDLC" button on Metaverse Desktop
		MouseClick "left", 64, 304

		; Wait for DDLC to open
		Sleep 9700

		; Check if we successfully got the ghost ending by seeing if there is a black pixel at Sayori's skirt.
		If PixelGetColor(533, 459) == "0x000000" {
			MsgBox "Ghost startup has been achieved after " Attempts " attempts.",, "iconi"
			Return
		}

		; Press "Exit DDLC" to return to Metaverse Desktop
		MouseClick "left", 117, 593

		; Wait for the confirmation pop-up to show up
		Sleep 250

		; Confirm exit DDLC
		MouseClick "left", 564, 389

		; Wait for the Start Menu to fully open up
		Sleep 2200
	}
}