Get paginated list of issues from gitlab with clojure/babashka

get_all_issues.clj

(defn get-all-issues
  "Holt alle Issues. Verwendet `iteration` für die Pagination."
  [gitlab-config project-id]
  (let [{:keys [gitlab-token gitlab-root]} gitlab-config
        curl-options {:raw-args ["--insecure"]
                      :debug true
                      :throw false
                      :headers {:PRIVATE-TOKEN gitlab-token
                                :Content-Type "application/json; charset=utf-8"}}
        step (fn step [marker-token]
               (let [url (str gitlab-root (format "/projects/%s/issues?per_page=100&page=%s" project-id marker-token))
                     response (b-curl/get url curl-options)
                     data (j response)]
                 {:response response :data data}))
        somef (fn somef [{:keys [data]}] (not (empty? data)))
        vf (fn vf [{:keys [data]}] data)
        kf (fn kf [{:keys [response]}] (let [next-page (-> response :headers (get "x-next-page"))
                                             next-marker (if (str/blank? next-page)
                                                           nil
                                                           (Integer/parseInt next-page))]
                                         next-marker))]
    (into [] cat (iteration step
                   :initk 1
                   :kf kf
                   :vf vf
                   :somef somef))))