python-webcolors

PKGBUILD

# Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
# Contributor: Sean Enck <enckse@gmail.com>
# Contributor: Lukas K. <lu at 0x83 dot eu>

_pkgname=webcolors
pkgbase=python-webcolors
pkgname=('python-webcolors' 'python2-webcolors')
pkgdesc="Library for working with HTML/CSS color formats in Python "
pkgver=1.7
pkgrel=1
url="https://github.com/ubernostrum/webcolors"
license=('BSD')
arch=("any")
makedepends=('python' 'python-setuptools' 'python2' 'python2-setuptools')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/ubernostrum/${_pkgname}/archive/${pkgver}.tar.gz")
sha512sums=('103692c6ee25ce7c70c11899722a7ce3adf6afc4ea62de6ecf422b2672c00b2e1dc386f05b3fb3211434895af253dc041c2da90e6c3dec29ea43673878bc3295')
#validpgpkeys=('') # TODO https://github.com/ubernostrum/webcolors/issues/5

prepare() {
    # Create a copy for the python2 package
    cp -r "${_pkgname}-${pkgver}" "python2-${_pkgname}-${pkgver}"
}

package_python-webcolors() {
    depends=('python')

    cd "${srcdir}/${_pkgname}-${pkgver}"
    python setup.py install --root="${pkgdir}" --optimize=1
    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-webcolors() {
    depends=('python2')

    cd "${srcdir}/python2-${_pkgname}-${pkgver}"
    python2 setup.py install --root="${pkgdir}" --optimize=1
    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}