python2-pyusb

PKGBUILD

# Maintainer: NicoHood <aur {at} nicohood {dot} de>
# Contributor: Nuno Araujo <nuno.araujo@russo79.com>
# Contributor: Limao Luo <luolimao+AUR@gmail.com>
# Contributor: Jason Giangrande <jgiangrande@clarku.edu>

_pkgname=pyusb
pkgbase=python-pyusb
pkgname=('python-pyusb' 'python2-pyusb')
pkgver=1.0.0
pkgrel=3
pkgdesc="A native Python module written in C which provides USB access."
arch=('any')
url="https://github.com/walac/${_pkgname}"
license=('custom')
makedepends=('python-distribute' 'python2-distribute')
conflicts=($_pkgname=$pkgver)
replaces=('python2-pyusb-beta')
source=("https://github.com/walac/${_pkgname}/archive/${pkgver}.tar.gz")
sha512sums=('af5549750140d12229202e8c32f48d6f2bbcda632b43763f7cefc51f63c61d5d9c4bf816842019729c911aedca792269a2cacad08d668d7ec569038b9979e3de')

prepare() {
    # Create a copy for the python2 package
    cp -r "${_pkgname}-${pkgver}" "python2-${_pkgname}-${pkgver}"
}

package_python-pyusb() {
    pkgdesc="A native Python module written in C which provides USB access."
    depends=('python' 'libusb')

    cd "${srcdir}/${_pkgname}-${pkgver}"
    python setup.py install --root=${pkgdir} --optimize=1
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-pyusb() {
    pkgdesc="A native Python module written in C which provides USB access."
    depends=('python2' 'libusb')

    cd "${srcdir}/python2-${_pkgname}-${pkgver}"
    python2 setup.py install --root=${pkgdir} --optimize=1
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}