python-astral

PKGBUILD

# Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
# Contributor: Gregoire Seux <grego_aur@familleseux.net>

_pkgname=astral
pkgbase=python-astral
pkgname=('python-astral' 'python2-astral')
pkgdesc="Python calculations for the position of the sun and moon."
pkgver=1.4.2
pkgrel=1
url="https://github.com/sffjunkie/astral"
license=('APACHE')
arch=("any")
makedepends=('python' 'python-setuptools' 'python2' 'python2-setuptools')
_commit=fadbf21bc34b89dd2afb128c441557259016c4bb
#source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/sffjunkie/${_pkgname}/archive/${pkgver}.tar.gz"
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/sffjunkie/${_pkgname}/archive/${_commit}.tar.gz")
sha512sums=('15c60149698e9160bbb1481e948b3b26f6ad45cd7280e68c779e88f8a44f8e537366a6063079c6e341239a9c7b3082dfae635f6e50df214125584df971a7a95b')
#validpgpkeys=('') # TODO https://github.com/sffjunkie/astral/issues/10

prepare() {
    # Create a copy for the python2 package
    cp -r "${_pkgname}-${_commit}" "python2-${_pkgname}-${_commit}"
}

package_python-astral() {
    depends=('python')

    cd "${srcdir}/${_pkgname}-${_commit}"
    python setup.py install --root="${pkgdir}" --optimize=1
}

package_python2-astral() {
    depends=('python2')

    cd "${srcdir}/python2-${_pkgname}-${_commit}"
    python2 setup.py install --root="${pkgdir}" --optimize=1
}