Problem.hs

module Problem where

bigBadMathProblem :: Integer -> Integer
bigBadMathProblem = (* 5)

Test.hs

{-# LANGUAGE TemplateHaskell #-}
module Test where

import           Problem
import           TH


$(precompute [1..1000])

TH.hs

module TH where

import           Language.Haskell.TH

import           Problem

precompute :: [Integer] -> DecsQ
precompute xs = do
  let name = mkName "lookupTable"
      patterns :: [Pat]
      patterns = map intToPat xs
      fnBodies :: [Body]
      fnBodies = map precomputeInteger xs
      precomputedClauses :: [Clause]
      precomputedClauses =
        zipWith (\pattern body -> Clause [pattern] body []) patterns fnBodies
      x' :: Name
      x' = mkName "x"
      bigBadMathProblem' :: Name
      bigBadMathProblem' = mkName "bigBadMathProblem"
      appBody :: Body
      appBody = NormalB $ AppE (VarE bigBadMathProblem') (VarE x')
      lastClause :: Clause
      lastClause = Clause [VarP x'] appBody []
      clauses :: [Clause]
      clauses = precomputedClauses ++ [lastClause]
  return [FunD name clauses]

intToPat :: Integer -> Pat
intToPat = LitP . IntegerL . toInteger

precomputeInteger :: Integer -> Body
precomputeInteger = NormalB . LitE . IntegerL . bigBadMathProblem