Haskell program to check if two inputs (command-line arguments) are anagrams (in terms of the 26 letters in the English alphabet)

anagram.hs

import Data.Char (toUpper)
import Data.List (sort)
import System.Environment (getArgs)
import System.Exit (exitWith, ExitCode(..))

data CheckAnagramError = NotEnoughArguments | EmptyInput

isAnagram :: String -> String -> Bool
isAnagram x y = normalize x == normalize y
    where
        normalize = sort . (filter (`elem` ['A'..'Z'])) . (map toUpper)

checkAnagram :: [String] -> Either CheckAnagramError Bool
checkAnagram xs = case xs of
    (x:y:_) ->
        if all (not . null) [x, y]
            then Right (isAnagram x y)
            else Left EmptyInput
    _ -> Left NotEnoughArguments

main :: IO ()
main = do
    args <- getArgs
    let result = checkAnagram args
    case result of
        Right True -> do
            putStrLn "Anagrams"
            exitWith ExitSuccess
        Right False -> do
            putStrLn "Not anagrams"
            exitWith $ ExitFailure 1
        Left e -> do
            case e of
                NotEnoughArguments -> putStrLn "Not enough arguments"
                EmptyInput -> putStrLn "Arguments must not be empty"
            exitWith $ ExitFailure 2