acsuite AUR package files

.SRCINFO

pkgbase = vapoursynth-tools-acsuite-git
	pkgdesc = Tools for Vapoursynth: acsuite (GIT version)
	pkgver = 3.0.0.r1.gc14204b
	pkgrel = 1
	url = https://github.com/OrangeChannel/acsuite
	arch = any
	license = GPL
	makedepends = git
	depends = vapoursynth
	depends = mkvtoolnix-cli
	provides = vapoursynth-tools-acsuite
	conflicts = vapoursynth-tools-acsuite
	source = acsuite::git+https://github.com/OrangeChannel/acsuite.git
	sha256sums = SKIP

pkgname = vapoursynth-tools-acsuite-git

PKGBUILD

# Maintainer:  Dave <orangechannel@pm.me>
# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=acsuite
pkgname=vapoursynth-tools-${_plug}-git
pkgver=3.0.0.r1.gc14204b
pkgrel=1
pkgdesc="Tools for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/OrangeChannel/acsuite'
license=('GPL')
depends=('vapoursynth'
         'mkvtoolnix-cli'
         )
makedepends=('git')
provides=("vapoursynth-tools-${_plug}")
conflicts=("vapoursynth-tools-${_plug}")
source=("${_plug}::git+https://github.com/OrangeChannel/acsuite.git")
sha256sums=('SKIP')

_site_packages="$(python -c "from distutils.sysconfig import get_python_lib; print(get_python_lib())")"

pkgver() {
  cd "${_plug}"
  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package(){
  cd "${_plug}"
  install -Dm644 "${_plug}.py" "${pkgdir}${_site_packages}/${_plug}.py"
  python -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/${_plug}.py"
  python -OO -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/${_plug}.py"

  install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
}