This snippet defines curried versions of lambda and define, and was originally posted on #scheme (Freenode IRC, 2007)

curried.scm

;;; Analogous to lambda, but curried.
(define-syntax curried
  (syntax-rules ()
    ((curried () body ...) (lambda () body ...))
    ((curried (arg) body ...) (lambda (arg) body ...))
    ((curried (arg args ...) body ...)
     (lambda (arg . rest)
       (let ((next (curried (args ...) body ...)))
         (if (null? rest)
             next
             (apply next rest)))))))

;;; Analogous to define, but curried.
(define-syntax define-curried
  (syntax-rules ()
    ((define-curried (name args ...) body ...)
     (define name (curried (args ...) body ...)))))



;;; Sample usage:
;;;
;;; (define-curried (foo x y z) (+ x (/ y z)))  ; foo has arity 3
;;;
;;; ((foo 3) 1 2)  ; (foo 3) is a procedure with arity 2
;;; ((foo 3 1) 2)  ; (foo 3 2) is a procedure with arity 1

This inspired some blog posts that expand on the idea:

• "Scheme code capsule: currying", José A Ortega-Ruiz, Programming Musings, 2007
• "Curried Scheme", Edward Kmett, The Comonad.Reader, 2009

Mirrored at: https://bitbucket.org/snippets/pjdelport/rkAB

Further work:

• "λ*: Beyond Currying", Jason Hemann, Daniel P. Friedman. Scheme and Functional Programming Workshop, 2013.