protontricks AUR 1.10.5

PKGBUILD

pkgname=protontricks
pkgver=1.10.5
pkgrel=1
pkgdesc="A wrapper that does winetricks things for Proton enabled games."
arch=('any')
url="https://github.com/Matoking/protontricks"
license=('GPL3')
depends=('python>=3.6' 'python-pillow' 'python-setuptools' 'python-vdf>=3.2' 'steam' 'winetricks' 'zenity')
makedepends=('python-build'
             'python-installer'
             'python-setuptools-scm'
             'python-wheel')
optdepends=('yad: Alternative to zenity, recommended by developer')
conflicts=('protontricks-git')
source=("https://files.pythonhosted.org/packages/7f/f5/b2dd5e219f1f109194f1d87004eea794499e4279ca2335c9d733079699ad/protontricks-1.10.5.tar.gz")
sha256sums=('4843dd78113e77fc97e38fafa45126129fc33e64b1ee53e2a770f19aac7263ba')

build() {
   cd "${pkgname}-${pkgver}"
   python -m build --wheel --no-isolation
}

package() {
   cd "${pkgname}-${pkgver}"
   python -m installer --destdir="${pkgdir}/" dist/*.whl
   install -D -m 0644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}