PKGBUILD for lollypop-transparent

PKGBUILD

# Maintainer: Dan Beste <dan.ray.beste@gmail.com>
# Contributor: Frederic Bezies < fredbezies at gmail dot com>
# Contributor: Ian Brunelli (brunelli) <ian@brunelli.me>

pkgname="lollypop-transparent"
_gitname="lollypop-transparent"
_gitname_orig="lollypop"
pkgdesc='Lollypop with a transparent background'
pkgver=0.9.304.r573.g20395d12
pkgrel=1
url='https://github.com/Rahix/lollypop-transparent'
arch=('x86_64')
license=('GPL3')
makedepends=('meson' 'ninja')
depends=(
  'appstream-glib' 'desktop-file-utils' 'gobject-introspection' 'gst-python'
  'gstreamer' 'gtk3' 'itstool' 'python-cairo' 'python-dbus' 'python-gobject'
  'python-pylast' 'totem-plparser'
)
optdepends=(
  'easytag: tag editing'
  'flatpak: Flatpak Portal'
  'gst-libav: FFmpeg plugin for GStreamer'
  'gst-plugins-bad: GStreamer Multimedia Framework Bad Plugins'
  'gst-plugins-base: GStreamer Multimedia Framework Base Plugins'
  'gst-plugins-base-libs: GStreamer Multimedia Framework Base Plugin libraries'
  'gst-plugins-good: GStreamer Multimedia Framework Good Plugins'
  'gst-plugins-ugly: GStreamer Multimedia Framework Ugly Plugins'
  'kid3-qt: Store covers in tags'
  'libsecret: Last.FM support'
  'python-wikipedia: Wikipedia support'
  'youtube-dl: YouTube playback'
)
conflicts=("${_gitname_orig}")
provides=("${_gitname_orig}")
source=(
  "git+https://github.com/Rahix/${_gitname}.git"
  "git+https://gitlab.gnome.org/gnumdk/${_gitname_orig}-po.git"
  "git+https://gitlab.gnome.org/gnumdk/${_gitname_orig}-portal.git" 
)
sha256sums=(
  'SKIP'
  'SKIP'
  'SKIP'
)

pkgver() {
  cd "${_gitname}"

  git describe --tags --long \
    | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${_gitname}"

  local -r submodules=(
  'lollypop-po'
  )

  for module in "${submodules[@]}"; do
    local submodule="subprojects/${module/lollypop-/}"
    git submodule init "${submodule}"
    git config "submodule.${submodule}.url" "${srcdir}/${module}"
    git submodule update "${submodule}"
  done

  cd ..
  cd "${_gitname}"

  if [[ -d build ]]; then
    # This should be removed when 'meson [OPTIONS] ..' can be run
    # repeatedly without generating an error.
    rm -rf build
  fi

  cd ..
  cd "${_gitname_orig}-portal"

  if [[ -d build ]]; then
    # This should be removed when 'meson [OPTIONS] ..' can be run
    # repeatedly without generating an error.
    rm -rf build
  fi
}

build() {
  cd "${_gitname}"

  meson build --prefix=/usr
  
  cd ..
  cd "${_gitname_orig}-portal"

  meson build --prefix=/usr
}

package() {
  cd "${_gitname}"

	DESTDIR="$pkgdir" ninja -C build install
	
  cd ..
  cd "${_gitname_orig}-portal"

	DESTDIR="$pkgdir" ninja -C build install
}

# vim: ts=2 sw=2 et: