Range implementation in Plorth + Class framework

class.plorth

: class
  swap class-create swap tuck "-prototype" + tuck const " new" + compile swap
  >symbol swap >word define
;

: class-extends
  "prototype" swap @ nip rot "__proto__" swap ! class
;

: class-create
  "fields" swap has-own?
  (
    "fields" swap @ array?
    (
      (
        tuck dup
        # Create setter.
        "!" swap + swap >string >source " swap !" + compile swap rot !
        # Create getter.
        swap dup "@" swap + swap >string >source " swap @" + compile swap rot !
      )
      swap for-each
      "fields" swap delete
    )
    ( drop )
    if-else
  )
  if
  "prototype" {} !
;

range.plorth

"./class" import

{
  "fields": [
    "current",
    "end",
    "stepper",
    "comparator",
  ],

  "constructor": (
    !end
    !current
    "+" >symbol swap !stepper
    "<" >symbol swap !comparator
  ),

  "reverse-stepper": (
    @stepper >string
    "-" >symbol swap
    "+" >symbol swap
    "+" = ?
  ),

  "reverse-comparator": (
    @comparator >string
    ">" >symbol swap
    "<" >symbol swap
    "<" = ?
  ),

  "reverse": (
    @current swap @end rot rot !end !current
    reverse-stepper swap !stepper
    reverse-comparator swap !comparator
  ),

  "has-next?": (
    dup @current swap @end swap @comparator nip call
  ),

  "next": (
    has-next?
    (
      dup
      @current swap @stepper nip 1 swap call
      dup rot !current swap
    )
    ( "Range has reached it's end." range-error throw )
    if-else
  )
} "range" class