VBA function for Cholesky decomposition

gistfile1.vb

Function CholeskyDecompose(matrix As Range)

Dim A, LTM() As Double, S As Double
Dim j As Long, K As Long, i As Long, N As Long, M As Long

A = matrix
N = matrix.Rows.Count
M = matrix.Columns.Count

If N <> M Then
    CholeskyDecompose = "Non-invertible matrix"
    Exit Function
End If

ReDim LTM(1 To N, 1 To N)

For j = 1 To N
    S = 0
    For K = 1 To j - 1
        S = S + LTM(j, K) ^ 2
    Next K
    
    LTM(j, j) = A(j, j) - S
    If LTM(j, j) <= 0 Then Exit For
    LTM(j, j) = Sqr(LTM(j, j))
    
    For i = j + 1 To N
        S = 0
        For K = 1 To j - 1
            S = S + LTM(i, K) * LTM(j, K)
        Next K
        LTM(i, j) = (A(i, j) - S) / LTM(j, j)
    Next i
Next j

CholeskyDecompose = LTM

End Function

Thanks for the implementation.
In line 24 where you have an I think it would be better to quit the function and report that the matrix is not Positive Semi Definite.
I also added in a check at the start to make sure the input matrix is symmetric.
Happy to contribute my code

Thanks!