TestDynamic.prg

DO wwDynamic
DO wwJsonSerializer

CLEAR

loCust = CREATEOBJECT("TestClass")
loItem = CREATEOBJECT("wwDynamic",loCust)

*loItem = CREATEOBJECT("wwDynamic")

? loItem.Class

loItem.Bogus = "This is bogus"
loItem.Entered = DATETIME()

? loItem.Bogus
? loItem.Entered

WITH loItem.Child 
  .Bogus2 = "Child Bogus"
  .Entered2 = DATETIME()

   ? .Bogus2
   ? .Entered2
ENDWITH

? loItem.cFirstName
? loItem.cLastName
? loItem.GetFullname()


loSer = CREATEOBJECT("wwJsonSerializer")
lcJson = loSer.Serialize(loItem,.T.)

? lcJson
_cliptext = lcJson



DEFINE CLASS TestClass as Custom


cFirstName = "Rick"
cLastName = "Strahl"

FUNCTION GetFullName()
RETURN this.cFirstname + " " + this.cLastname

ENDDEFINE

wwDynamic.prg

SET PROCEDURE TO wwDynamic ADDITIVE


*************************************************************
DEFINE CLASS wwDynamic AS RELATION
*************************************************************
*: original Author: Marco Plaza, 2018 @vfp2nfox
*:     modified by: Rick Strahl
*************************************************************

__oReference = null

*** Intercept access to unknown properties and create
FUNCTION THIS_Access(lcPropertyOrMethod)

If Lower(lcPropertyOrMethod) ==  "__oreference" OR ;
   Pemstatus(this,lcPropertyOrMethod,5)
	RETURN this
Endif

If !Pemstatus(this.__oReference,lcPropertyOrMethod,5)
   AddProperty(this.__oReference,lcPropertyOrMethod,Createobject('wwDynamic'))
ENDIF
	
RETURN this.__oReference
ENDFUNC



************************************************************************
*  Init
****************************************
***  Function:
***    Assume:
***      Pass:
***    Return:
************************************************************************
FUNCTION Init(loBaseType)

IF !VARTYPE(loBaseType) = "O"
   this.__oReference = CREATEOBJECT("Empty")
ELSE 
   this.__oReference = loBaseType
ENDIF   

ENDFUNC
*   Init

ENDDEFINE
*EOC wwDynamic 

wwJsonSerializer.prg

*** This change is required in wwJsonSerializer::WriteValue() to serialize wwDynamic properly 
*** as DTO objects rather than serializing the dynamic instance itself

*** Skip over wwDynamic instance and serialize just the reference
CASE lcValueType = "C" AND LOWER(lvValue.Class) = "wwdynamic"
   this.WriteObject( EVALUATE("lvValue.__oReference"))