dufus-diff.clj

dufus-diff.clj

(defn diff-branches [repo branch1 branch2]
  (letfn [(tree-iterator [^Repository repo branch]
            (let [head (.exactRef repo branch)]
              (with-open [walk (RevWalk. repo)]
                (let [commit (.parseCommit repo (.getObjectId head))
                      tree   (.parseTree walk (.getId (.getTree commit)))
                      parser (CanonicalTreeParser.)]
                  (with-open [reader (.newObjectReader repo)]
                    (.reset parser reader (.getId tree)))
                  (.dispose walk)
                  parser))))
          (as-data [^DiffEntry entry]
            {:old/id   (.getOldId entry)
             :old/path (.getOldPath entry)
             :old/mode (str (.getOldMode entry))
             :new/id   (.getNewId entry)
             :new/path (.getNewPath entry)
             :new/mode (str (.getNewMode entry))
             :type     (keyword (.name (.getChangeType entry)))})]
    (let [git  (->repo repo)
          repo (.getRepository git)
          t1   (tree-iterator repo (str "refs/heads/" branch1))
          t2   (tree-iterator repo (str "refs/heads/" branch2))]
      (set (map as-data
                (-> (.diff git)
                    (.setOldTree t1)
                    (.setNewTree t2)
                    (.call)))))))