make_openssl_102l_vs2015_32_xp.cmd

:: See file: INSTALL
:: See file: INSTALL.W32

:: Edit: \util\pl\VC-32.pl 
:: 1) if ($FLAVOR =~ /WIN64/)  ...  $lflags="/nologo /subsystem:console /opt:ref"
::    /subsystem:console -> /subsystem:console,5.02
:: 2) else # Win32  ...  $lflags="/nologo /subsystem:console /opt:ref"
::    /subsystem:console -> /subsystem:console,5.01
::
:: INIT XP x32 TOOLCHAIN
::
set SDK71PATH=%ProgramFiles%\Microsoft SDKs\Windows\7.1A
path %SDK71PATH%\Bin;%PATH%
set INCLUDE=%SDK71PATH%\Include;%INCLUDE%
set LIB=%SDK71PATH%\Lib;%LIB%

::
:: INIT VC++2015 x32
::
:: VS140COMNTOOLS_in_VS2017_fix.reg
:: https://gist.github.com/Ruzzz/38dc70f4b850dd5e379f8cfa2cbf09a3
if not exist "%VS140COMNTOOLS%\..\..\VC\bin\vcvars32.bat" goto :ERROR
call "%VS140COMNTOOLS%\..\..\VC\bin\vcvars32.bat"
if ERRORLEVEL 1 goto :ERROR

::
:: BUILD
::
set __OPENSSL_VER__=102l
:: MAYBE (UN)COMMENT STEP-BY-STEP
perl Configure VC-WIN32 no-shared threads --prefix=C:\Dev\OpenSSL_%__OPENSSL_VER__%_vs2015_32_xp --openssldir=C:\Dev\OpenSSL_Config_%__OPENSSL_VER__% -D_USING_V110_SDK71_
if ERRORLEVEL 1 goto :ERROR
call ms\do_ms
if ERRORLEVEL 1 goto :ERROR
call ms\do_nasm
if ERRORLEVEL 1 goto :ERROR
nmake -f ms\nt.mak clean
nmake -f ms\nt.mak
if ERRORLEVEL 1 goto :ERROR
nmake -f ms\nt.mak install
if ERRORLEVEL 1 goto :ERROR
pause
goto :EOF

:ERROR
pause