PKGBUILD for sxiv fork with color management support

PKGBUILD

# Maintainer:  Sven Karsten Greiner <sven@sammyshp.de>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Bert Muennich <muennich at informatik.hu-berlin.de>
# Contributor: Brad Fanella <bradfanella@archlinux.us>

_pkgname=sxiv
pkgname=${_pkgname}-cm-git
pkgver=r608.b64c2b4
pkgrel=1
pkgdesc='Simple X Image Viewer'
arch=('i686' 'x86_64')
license=('GPL2')
install=sxiv.install
url='https://github.com/haasn/sxiv'
depends=('imlib2' 'desktop-file-utils' 'xdg-utils' 'hicolor-icon-theme' 'libexif' 'lcms2')
makedepends=('git')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+${url}.git")
md5sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${_pkgname}"
  ln -s config.def.h config.h
}

build() {
  make -C "${_pkgname}"
}

package() {
  cd "${_pkgname}"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  make -C icon PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 sxiv.desktop "$pkgdir"/usr/share/applications/sxiv.desktop
}

sxiv.install

post_install() {
  xdg-icon-resource forceupdate --theme hicolor &> /dev/null
  update-desktop-database -q
}

post_upgrade() {
  post_install
}

post_remove() {
  post_install
}