PKGBULID.sh

#Maintainer : Sasasu <lizhaolong0123@gmail.com>
pkgbase=iaito-git
pkgname=(radare2-iaito iaito-git)
pkgver=r266.d033b52
pkgrel=1
_gitname=iaito
pkgdesc="A Qt and C++ GUI for radare2 reverse engineering framework"
arch=('x86_64' 'i686')
url="https://github.com/hteso/iaito"
license=('GPL3')
depends=()
makedepends=('gcc' 'git' 'qconf' 'qt5-base' 'qt5-webengine')
source=('git://github.com/hteso/iaito')
md5sums=('SKIP')
pkgver() {
  cd "$_gitname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare(){
  cd "$srcdir/iaito"
  git submodule update --init
}
build() {
  #bulid r2
  cd "$srcdir/iaito"
  cd radare2
  ./configure --prefix=/usr \
    --with-syscapstone \
    --with-syszip \
    --with-openssl
  make
  
  #bulid iaito
  cd "$srcdir/iaito"
  mkdir build ; cd build
  qmake PREFIX=/usr APPIMAGE=1 ../src
  make
}
package_radare2-iaito() {
  depends=('sh' 'capstone' 'openssl' 'libzip')
  conflicts=(iaito-git iaito)
  provides=(iaito)
  cd "$srcdir/iaito/radare2"
  make DESTDIR="${pkgdir}" install
}
package_iaito-git(){
  depends=('qt5-base' 'qt5-webengine')
  cd "$srcdir/iaito"
  cd build
  make INSTALL_ROOT="$pkgdir/" install
}